Re: [proaudio] Ardour behind

[Björn Thorwirth <bjoern.thorwirth@xxxxxxxxxx>]

Hi!

I've updated the ebuild. This works for me.


Best regards,

björn

Am Dienstag, den 30.03.2010, 12:26 +0200 schrieb Arve Barsnes:
> 2.8.2 is in main portage, but I guess the main reason for it not being
> updated anymore is that the latest versions are only downloadable
> after registering at the website?
> 
> Arve
> 
> On Tue, Mar 30, 2010 at 12:11 PM, Alex Montgomery
> <apmontgomery@xxxxxxxxx> wrote:
> > Hello,
> >
> > I was wondering why the non-svn ebuilds (i.e. not 2.999 or 3.9999) are
> > at version 2.7.1 even though there have been several official releases
> > since then. Does everyone use the live ebuilds? I tried using the
> > 2.999 ebuild for awhile, but the code in svn can be flaky and crashes
> > often. I had to revert to the 2.7.1 ebuild, which is much more
> > crash-resistant, but has several known issues that have been fixed in
> > later versions. Particularly, users of midi surfaces can end up
> > destroying data with versions prior to 2.8.5:
> > http://ardour.org/node/3292
> >
> > Is it hard to update the ebuild to 2.8.7, or is there another good
> > reason to stay at 2.7.1? I'd happily help with the update.
> >
> > Thanks,
> > -- Alex
> >
> >
> >
> 
> 
> 
-- 
Bjoern Thorwirth, Zentrum für Medizinische Biotechnologie,
Universität Duisburg-Essen, Universitätsstr. 2, 45117 Essen, Germany
phone +49 201 183-4026, bjoern.thorwirth@xxxxxxxxxx


# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit eutils toolchain-funcs fdo-mime flag-o-matic versionator

DESCRIPTION="multi-track hard disk recording software"
HOMEPAGE="http://ardour.org/";

SRC_URI="http://ardour.org/files/releases/${P/_p/-}.tar.bz2";


LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="altivec debug freesound nls sse lv2 vst sys-libs"

RDEPEND=">=media-libs/liblrdf-0.4.0
	media-libs/aubio
	>=media-libs/raptor-1.4.2
	>=media-sound/jack-audio-connection-kit-0.116.2
	>=dev-libs/glib-2.10.3
	>=x11-libs/gtk+-2.8.8
	media-libs/flac
	>=media-libs/alsa-lib-1.0.14a-r1
	>=media-libs/libsamplerate-0.1.1-r1
	media-libs/liblo
	>=dev-libs/libxml2-2.6.0
	dev-libs/libxslt
	media-libs/vamp-plugin-sdk
	=sci-libs/fftw-3*
	freesound? ( net-misc/curl )
	lv2? ( >=media-libs/slv2-0.6.1 )
	sys-libs? ( >=dev-libs/libsigc++-2.0
		>=dev-cpp/glibmm-2.4
		>=dev-cpp/cairomm-1.0
		>=dev-cpp/gtkmm-2.8
		>=dev-libs/atk-1.6
		>=x11-libs/pango-1.4
		>=dev-cpp/libgnomecanvasmm-2.12.0
		>=media-libs/libsndfile-1.0.16
		>=media-libs/libsoundtouch-1.0 )"
		# currently internal rubberband is used
		# that needs fftw3 and vamp-sdk, but it rocks, so enable by default"

DEPEND="${RDEPEND}
	sys-devel/libtool
	dev-libs/boost
	dev-util/pkgconfig
	dev-util/scons
	nls? ( sys-devel/gettext )"

S=${WORKDIR}/${P%_p*}


pkg_setup(){
	einfo "this ebuild fetches from the svn maintaince"
	einfo "ardour-2.X branch"
	# issue with ACLOCAL_FLAGS if set to a wrong value
	if use sys-libs;then
		ewarn "You are trying to use the system libraries"
		ewarn "instead the ones provided by ardour"
		ewarn "No upstream support for doing so. Use at your own risk!!!"
		ewarn "To use the ardour provided libs remerge with:"
		ewarn "USE=\"-sys-libs\" emerge =${P}"

		epause 3s
	fi

	if use amd64 && use vst; then
		eerror "${P} currently does not compile with VST support on amd64!"
		eerror "Please unset VST useflag."
		die
	fi
}

src_prepare() {
	ewarn "You need to manually download the source from http://ardour.org to"
	ewarn "use this ebuild. Place it in your distfiles directory."
	use sys-libs && epatch "${FILESDIR}/${PN}-2.0.3-sndfile-external.patch"
#	Doesn't apply to 2.8 anymore. Do we need a new patch ?
# 	how can we extract the -march flag from our system CFLAGS and add it to the
# 	scons ARCH variable ?
#	epatch "${FILESDIR}/${PN}-2.4-cflags.patch"
}

src_compile() {
	# Required for scons to "see" intermediate install location
	mkdir -p ${D}

	local myconf=""
	(use sse || use altivec) && myconf="FPU_OPTIMIZATION=1"
	! use altivec; myconf="${myconf} ALTIVEC=$?"
	! use debug; myconf="${myconf} ARDOUR_DEBUG=$?"
	! use nls; myconf="${myconf} NLS=$?"
	! use vst; myconf="${myconf} VST=$?"
	! use sys-libs; myconf="${myconf} SYSLIBS=$?"
	! use sse; myconf="${myconf} USE_SSE_EVERYWHERE=$? BUILD_SSE_OPTIMIZATIONS=$?"
	! use lv2; myconf="${myconf} LV2=$?"

	# static settings
	myconf="${myconf} DESTDIR=${D} PREFIX=/usr KSI=0"
	einfo "scons configure options : \"${myconf}\""

	cd ${S}
	scons ${myconf}	${MAKEOPTS} || die "compilation failed"
}

src_install() {
	scons install || die "make install failed"
	if use vst;then
		mv "${D}"/usr/bin/ardourvst "${D}"/usr/bin/ardour2
	fi

	dodoc DOCUMENTATION/*

	newicon "${S}/icons/icon/ardour_icon_mac.png" "ardour2.png"
	make_desktop_entry "ardour2" "Ardour2" "ardour2" "AudioVideo;Audio"
}

pkg_postinst() {
	fdo-mime_mime_database_update
	fdo-mime_desktop_database_update
	
	ewarn "---------------- WARNING -------------------"
	ewarn ""
	ewarn "MAKE BACKUPS OF THE SESSION FILES BEFORE TRYING THIS VERSION."
	ewarn ""
	ewarn "The simplest way to address this is to make a copy of the session file itself"
	ewarn "(e.g mysession/mysession.ardour) and make that file unreadable using chmod(1)."
	ewarn ""
}