[proaudio] Mixxx 9999 update

[Alex Barker <alex@xxxxxxxxxx>]

Good morning,

Mixxx 9999 has stopped compiling with what I suspect is related to 
qtcore[-debug].  I have attached an update ebuild and patch that 
"resolves" the problem.  I am still working with upstream and gentoo-qt 
to determine the best course of action to resolve this issue more 
reliably.  I have also removed the files/mixxx-9999-cflags.patch because 
its not really needed.

Alex


--- /usr/local/portage/media-sound/mixxx/mixxx-9999.ebuild 2014-01-18 
09:43:05.649572486 -0800
+++ /var/lib/layman/pro-audio/media-sound/mixxx/mixxx-9999.ebuild 
2013-12-09 00:25:06.526098450 -0800
@@ -56,7 +56,7 @@
 S=${S}/${PN}

 src_prepare() {
-       epatch "${FILESDIR}"/${P}-qtdebug.patch
+       epatch "${FILESDIR}"/${P}-cflags.patch
        epatch "${FILESDIR}"/${P}-system-libs.patch
        epatch "${FILESDIR}"/${P}-docs.patch


# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

inherit eutils git-2 multilib scons-utils toolchain-funcs

DESCRIPTION="A Qt based Digital DJ tool"
HOMEPAGE="http://www.mixxx.org/";
EGIT_REPO_URI="git://github.com/mixxxdj/${PN}.git"
EGIT_BRANCH="master"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="aac debug doc hid mp3 mp4 pulseaudio shout wavpack"

RDEPEND="dev-libs/protobuf
	media-libs/chromaprint
	>=media-libs/fidlib-0.9.10-r1
	media-libs/flac
	media-libs/libid3tag
	media-libs/libogg
	media-libs/libsndfile
	>=media-libs/libsoundtouch-1.5
	media-libs/libvorbis
	>=media-libs/portaudio-19_pre
	media-libs/portmidi
	media-libs/rubberband
	media-libs/taglib
	media-libs/vamp-plugin-sdk
	sci-libs/fftw:3.0
	virtual/glu
	virtual/opengl
	dev-qt/qtgui:4
	dev-qt/qtopengl:4
	dev-qt/qtsql:4
	dev-qt/qtsvg:4
	dev-qt/qttest:4
	dev-qt/qtwebkit:4
	dev-qt/qtxmlpatterns:4
	aac? (
		media-libs/faad2
		media-libs/libmp4v2:0
	)
	hid? ( dev-libs/hidapi )
	mp3? ( media-libs/libmad )
	mp4? ( media-libs/libmp4v2 )
	pulseaudio? ( media-sound/pulseaudio )
	shout? ( media-libs/libshout )
	wavpack? ( media-sound/wavpack )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

S=${S}/${PN}

src_prepare() {
	epatch "${FILESDIR}"/${P}-qtdebug.patch
	epatch "${FILESDIR}"/${P}-system-libs.patch
	epatch "${FILESDIR}"/${P}-docs.patch

	# use multilib compatible directory for plugins
	sed -i -e "/unix_lib_path =/s/'lib'/'$(get_libdir)'/" src/SConscript || die

	# alter startup command when pulseaudio support is disabled
	if ! use pulseaudio ; then
		sed -i -e 's:pasuspender ::' src/mixxx.desktop || die
	fi
}

src_configure() {
	myesconsargs=(
		prefix="${EPREFIX}/usr"
		qtdir="${EPREFIX}/usr/$(get_libdir)/qt4"
		hifieq=1
		vinylcontrol=1
		optimize=0
		$(use_scons aac faad)
		$(use_scons debug qdebug)
		$(use_scons hid hid)
		$(use_scons mp3 mad)
		$(use_scons mp4 m4a)
		$(use_scons shout shoutcast)
		$(use_scons wavpack wv)
	)
}

src_compile() {
	CC="$(tc-getCC)" CXX="$(tc-getCXX)" LINKFLAGS="${LDFLAGS}" \
	LIBPATH="${EPREFIX}/usr/$(get_libdir)" escons
}

src_install() {
	CC="$(tc-getCC)" CXX="$(tc-getCXX)" LINKFLAGS="${LDFLAGS}" \
	LIBPATH="${EPREFIX}/usr/$(get_libdir)" escons install \
		install_root="${ED}"/usr

	dodoc README Mixxx-Manual.pdf
}

--- src/util/debug.orig.h	2014-01-17 19:14:52.152835237 -0800
+++ src/util/debug.h	2014-01-17 19:14:15.220923215 -0800
@@ -13,8 +13,10 @@
 template <typename T>
 QString toDebugString(const T& object) {
     QString output;
+#ifndef QT_NO_DEBUG_STREAM
     QDebug deb(&output);
     deb << object;
+#endif
     return output;
 }