Re: [proaudio] [1944] fix for amd64 / !amd64 : only amd64 need 32bit flag for jack-audio-connection-kit

[Gavin Pryke <gavinlee303@xxxxxxxxx>]

I fat fingered the last ebuild since changing to the waf-utils eclass broke 
the install locations.

This ebuild should work, sorry...


# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
inherit eutils multilib toolchain-funcs

DESCRIPTION="JACK is a sound server system for handling real-time, low latency audio and MIDI"
HOMEPAGE="http://www.jackaudio.org";
SRC_URI="http://www.grame.fr/~letz/jack-${PV}.tar.bz2";

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa celt +dbus doc freebob ieee1394 jackd multilib"

RDEPEND=">=media-libs/libsndfile-1.0.0
	media-libs/libsamplerate
	alsa? ( >=media-libs/alsa-lib-0.9.1 )
	dbus? ( sys-apps/dbus )
	celt? ( media-libs/celt )
	ieee1394? ( media-libs/libffado )
	freebob? ( sys-libs/libfreebob )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( app-doc/doxygen )"

S="${WORKDIR}/jack-${PV}"

pkg_setup() {
	if ! use dbus && ! use jackd ; then
		eerror "For ${PN} to function,"
		eerror "USE=\"dbus\" and/or USE=\"jackd\" flags needs to be enabled"
		die "Invalid USE flags for ${PN} package, enable dbus and/or jackd"
	fi
}

src_configure() {
	local mylibdir=
	if use multilib || has_multilib_profile ; then
		mylibdir="--libdir=/$(get_libdir)"
	else
		mylibdir="--libdir32=/$(get_libdir)"
	fi

	tc-export CC CXX CPP AR RANLIB
	CCFLAGS="${CXXFLAGS}" LINKFLAGS="${LDFLAGS}" ./waf configure \
		--prefix="/usr" --mandir="/share/man/man1" \
		${mylibdir} \
		$(use alsa && echo --alsa) \
		$(use celt && echo --celt) \
		$(use dbus && echo --dbus) \
		$(use doc && echo --doxygen) \
		$(use ieee1394 && echo --firewire) \
		$(use freebob && echo --freebob) \
		$(use jackd && echo --classic) \
		$(use multilib || has_multilib_profile && echo --mixed) || die
}

src_compile() {
	./waf build || die
}

src_install() {
	./waf --destdir="${D}" install || die
	dodoc ChangeLog README README_NETJACK2 TODO
}

pkg_postinst() {
	if ! use alsa; then
		einfo "NOTE: alsa has not been enabled as a USE flag, enable it to"
		einfo "utilise alsa and drive your sound card for audio output"
	fi
	if use dbus && use jackd; then
		einfo "WARNING !! mixing both jackd and jackdbus may cause issues:"
		einfo "WARNING !! jackdbus does not use .jackdrc nor qjackctl settings"
	fi
}