[proaudio] psychosynth-0.1.2.ebuild

[Gavin Pryke <gavinlee303@xxxxxxxxxxxxxx>]

Hi

Some update to psychosynth as I wanted to check out the new version.
Added EAPI=1 and default for +psynth3d to be built, also added flag in 
metadata.xml for this. A check for at least one audio USE flag otherwise 
psychosynth does not build, make repoman a bit happier too.

I would like to know which is the preferred way to send updates for the 
pro-audio tree here, do I attach separate files or a diff of the tree? I 
currently imported the pro-audio tree into git-svn and playing with it there 
and have some branches made that contain patches that I don't know what to do 
with, seems easier to send a recursive diff of that part of the tree with all 
modifications made, but I don't know how it would be easiest for you.

Thanks!
Gav

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=1

inherit autotools

RESTRICT="mirror"
DESCRIPTION="Free software synthesizer inspired by the ideas of the Reactable"
HOMEPAGE="http://www.psychosynth.com/";
SRC_URI="http://forja.rediris.es/frs/download.php/707/${P}.tar.gz";

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="alsa jack +psynth3d oss sndfile vorbis xml osc"

DEPEND="osc? ( >=media-libs/liblo-0.24 )
	>=media-libs/libsoundtouch-1.3.1-r1
	alsa? ( >=media-libs/alsa-lib-1.0.14a-r1 )
	jack? ( >=media-sound/jack-audio-connection-kit-0.103.0 )
	psynth3d? ( >=dev-games/cegui-0.5.0b-r3
				>=dev-games/ois-1.2.0
				>=dev-games/ogre-1.4.7 )
	sndfile? ( >=media-libs/libsndfile-1.0.17-r1 )
	vorbis? ( >=media-libs/libvorbis-1.2.0 )
	xml? ( >=dev-libs/libxml2-2.6.31 )"

RDEPEND="${DEPEND}"
S="${WORKDIR}/${PN}-0.1.1"

pkg_setup() {
	if use psynth3d; then
		if ! built_with_use dev-games/ogre cegui devil; then
			eerror "You need to compile dev-games/ogre with"
			eerror "USE=\"cegui devil\"!"
			die "Deps missing"
		fi
	fi
	if ! use alsa && ! use jack && ! use oss; then
		eerror "you need to enable either alsa, jack or oss USE flag, or"
		eerror "psychosynth will not compile"
		die "No audio system enabled"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# fix up soundtouch checks in configure.ac
	sed -i -e "s/\[\ libSoundTouch\ \]/\[\ soundtouch-1.0\ \]/"	\
		"${S}/configure.ac" || die "sed of configure.ac failed"

	# gcc-4.3
	epatch "${FILESDIR}/${PN}-0.1.1-gcc43.patch"

	# AT_M4DIR="." fails too, so...
	sed -i -e 's:-I m4:-I .:' Makefile.in Makefile.am || die

	eautoreconf
}

src_compile() {
	econf  $(use_enable alsa) \
		$(use_enable jack) \
		$(use_enable psynth3d) \
		$(use_enable sndfile) \
		$(use_enable vorbis) \
		$(use_enable xml libxml) \
		$(use_enable oss) || die "configure failed"
	emake || die "make failed"
}

src_install() {
	make DESTDIR="${D}" install || die "install failed"
}

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd";>
<pkgmetadata>
	<herd>no-herd</herd>
	<maintainer>
		<email>proaudio@xxxxxxxxxxxxx</email>
		<name>pro-audio overlay team</name>
	</maintainer>
	<use>
		<flag name='psynth3d'>Build the 3D GUI using dev-games/ogre</flag>
	</use>
</pkgmetadata>