[proaudio] Audacity and jack > 103.0 (ish)

[rob <rob@xxxxxxxxxxxxxxx>]

Hi

I just attempted to build audacity 1.3.2-r1 with jackd 0.107.5 - and all 
I got was a lousy build error :)

The gentoo devs have decided not to fix the issue 
(http://bugs.gentoo.org/show_bug.cgi?id=179758), but their rationale 
(whilst sensible) doesn't yield a working Audacity :(

Attached is a modified 1.3.2-r1 ebuild and the patch to remove 
jack_port_[un]lock calls which were removed somewhere after jack 103.0.

If it's sensible, would you add a 1.3.2-r2 ebuild to proaudio with a 
dependency on jack > 103.0?

cheers
R

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/audacity/audacity-1.3.2-r1.ebuild,v 1.11 2007/05/17 04:32:08 josejx Exp $

inherit eutils autotools wxwidgets

IUSE="flac ladspa libsamplerate mp3 sse unicode vorbis"

MY_P="${PN}-src-${PV}"
DESCRIPTION="Free crossplatform audio editor"
HOMEPAGE="http://audacity.sourceforge.net/";
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ppc ppc64 sparc x86"
RESTRICT="test"

DEPEND="=x11-libs/wxGTK-2.6*
	>=app-arch/zip-2.3
	dev-libs/expat
	vorbis? ( >=media-libs/libvorbis-1.0 )
	mp3? ( >=media-libs/libmad-0.14.2b
		media-libs/libid3tag )
	flac? ( media-libs/flac )
	>=media-libs/libsndfile-1.0.0
	libsamplerate? ( >=media-libs/libsamplerate-0.1.2 )"
RDEPEND="${DEPEND}
	mp3? ( >=media-sound/lame-3.70 )"

S="${WORKDIR}/${MY_P}-beta"

src_unpack() {
	unpack ${A}

	cd "${S}"
	epatch "${FILESDIR}"/${P}-jack-lock.patch
	epatch "${FILESDIR}"/${P}-gentoo.patch
	if ! use sse ; then
		epatch "${FILESDIR}"/${P}-no-msse.patch
		epatch "${FILESDIR}"/${P}-disable-optimization.patch
	fi
	epatch "${FILESDIR}/${P}+flac-1.1.3.patch"
	epatch "${FILESDIR}/${P}-libnyquistp.patch"
	epatch "${FILESDIR}/${P}-desktopentry.patch"

	eautoreconf || die
	pushd "${S}"/lib-src/soundtouch
	eautoreconf
	popd
}

src_compile() {
	local myconf
	WX_GTK_VER="2.6"

	if use unicode; then
		need-wxwidgets unicode
	else
		need-wxwidgets gtk2
	fi

	myconf="${myconf} --with-libsndfile=system"
	myconf="${myconf} --with-libexpat=system"

	if use libsamplerate ; then
		myconf="${myconf} --with-libsamplerate=system --without-libresample"
	else
		myconf="${myconf} --without-libsamplerate" # --with-libresample=local
	fi

	econf \
		$(use_enable unicode) \
		$(use_with ladspa) \
		$(use_with vorbis vorbis system) \
		$(use_with mp3 libmad system) \
		$(use_with mp3 id3tag system) \
		$(use_with flac flac system) \
		${myconf} || die

	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die

	# Remove bad doc install
	rm -rf "${D}"/usr/share/doc

	# Install our docs
	dodoc README.txt

	insinto /usr/share/audacity/
	newins images/AudacityLogo48x48.xpm audacity.xpm
}

diff -Naur audacity-src-1.3.2-beta/lib-src/portaudio-v19/src/hostapi/jack/pa_jack.c audacity-src-1.3.2-beta-jack_lock_patch/lib-src/portaudio-v19/src/hostapi/jack/pa_jack.c
--- audacity-src-1.3.2-beta/lib-src/portaudio-v19/src/hostapi/jack/pa_jack.c	2006-10-29 00:05:49.000000000 +0100
+++ audacity-src-1.3.2-beta-jack_lock_patch/lib-src/portaudio-v19/src/hostapi/jack/pa_jack.c	2007-10-25 19:47:49.000000000 +0100
@@ -1669,27 +1669,19 @@
     {
         for( i = 0; i < stream->num_incoming_connections; i++ )
         {
-            UNLESS( !jack_port_lock( stream->jack_client, stream->local_input_ports[i] ),
-                    paUnanticipatedHostError );
             if( jack_port_connected( stream->local_input_ports[i] ) )
             {
                 UNLESS( !jack_port_disconnect( stream->jack_client, stream->local_input_ports[i] ),
                         paUnanticipatedHostError );
             }
-            UNLESS( !jack_port_unlock( stream->jack_client, stream->local_input_ports[i] ),
-                    paUnanticipatedHostError );
         }
         for( i = 0; i < stream->num_outgoing_connections; i++ )
         {
-            UNLESS( !jack_port_lock( stream->jack_client, stream->local_output_ports[i] ),
-                    paUnanticipatedHostError );
             if( jack_port_connected( stream->local_output_ports[i] ) )
             {
                 UNLESS( !jack_port_disconnect( stream->jack_client, stream->local_output_ports[i] ),
                         paUnanticipatedHostError );
             }
-            UNLESS( !jack_port_unlock( stream->jack_client, stream->local_output_ports[i] ),
-                    paUnanticipatedHostError );
         }
     }